open System

​

type Prize  = Car | Goat

type Door   = Door of Prize

type Result = Win | Lose

type Choice = Stay | Change

​

let rand = new Random(DateTime.UtcNow.Ticks |> int)

let newGame () =

    [| Door Car; Door Goat; Door Goat |] 

    |> Array.sortBy (fun _ -> rand.NextDouble())

​

let reveal (doors : Door[]) choice =

    { 0..2 }

    |> Seq.filter ((<>) choice)

    |> Seq.filter (fun idx -> doors.[idx] = Door Goat)

    |> Seq.head

​

let play strategy (doors : Door[]) =

    let choice   = rand.Next(doors.Length)

    let revealed = reveal doors choice

    let choice   = 

        match strategy choice revealed with

        | Stay   -> choice

        | Change -> 

            { 0..2 }

            |> Seq.filter (fun idx -> 

                idx <> choice && idx <> revealed)

            |> Seq.head

    if doors.[choice] = Door Car then Win else Lose

​

let strategyA _ _ = Stay

let strategyB _ _ = Change

let strategyC _ _ =

    if rand.NextDouble() > 0.5 then Stay else Change

​

let getResults strategy = 

    { 1..1000 }

    |> Seq.filter (fun _ -> 

        newGame() |> play strategy |> ((=) Win))

    |> Seq.length

​

let resultsA = getResults strategyA

let resultsB = getResults strategyB

let resultsC = getResults strategyC

​

printfn "Stay : %d/1000 wins | Change : %d/1000 wins | Random : %d/1000 wins" 

        resultsA resultsB resultsC