open NLog

open Microsoft.Extensions.Configuration

​

// Logging module

[<Interface>]

type ILoggerProvider =

    abstract Logger: ILogger

​

let getLogger (env: #ILoggerProvider) = env.Logger

​

// Configuration module

[<Interface>]

type IConfigurationProvider =

    abstract Configuration: IConfiguration

​

let getConfiguration (env: #IConfigurationProvider) = env.Configuration

​

// Business logic module

let doSomething env = 

    let logger = getLogger env

    logger.Debug("Do something")

    // Do something

​

let doSomethingWithConfiguration env = 

    let logger = getLogger env

    let configuration = getConfiguration env

    let input = configuration.["input"]

    logger.Debug(input)

    // Do something

​

// Application level

[<Interface>] 

type IEnvironment = 

    inherit ILoggerProvider 

    inherit IConfigurationProvider

let createEnvironment (logger, configuration) = 

    { new IEnvironment with

        member self.Logger = logger 

        member self.Configuration = configuration }

​

let createLogger () = 

    let nlogTarget = new Targets.ConsoleTarget(Layout = Layouts.SimpleLayout("${message}"))

    let nLogConfig = Config.LoggingConfiguration()

    nLogConfig.AddRuleForAllLevels(nlogTarget)

    LogManager.Configuration <- nLogConfig

    LogManager.GetCurrentClassLogger()

let createConfiguration () =

    ConfigurationBuilder()

        .AddInMemoryCollection(dict ["input", "Some input"])

        .Build()

​

let logger = createLogger ()

let configuration = createConfiguration ()

let env = createEnvironment (logger, configuration)

​

doSomething env

doSomethingWithConfiguration env

​