////// Define all types of resources here

type ResourceType =

| Wood

| Wheat

| Bread

​

type Resource = {

    Type: ResourceType

    Amount: int

}

​

let formatResource resource = 

    sprintf "    %d %A" resource.Amount resource.Type

​

let formatResources resources = 

    resources

    |> Seq.map formatResource 

    |> String.concat "\n"

​

let createResource rtype amount = 

    { Type = rtype; Amount = amount }

​

let rec consume num rtype resources= 

    match resources with

    | [] -> [ createResource rtype -num ]

    | x::xs -> 

        if (x.Type = rtype) 

        then { x with Amount = x.Amount - num } :: xs

        else x :: consume num rtype xs

​

let rec produce num rtype resources =

    match resources with

    | [] -> [ createResource rtype num ]

    | x::xs ->

        if (x.Type = rtype) 

        then { x with Amount = x.Amount + num } :: xs

        else x :: produce num rtype xs

​

////// Define all types of workers here

type WorkerType =

| Peasant

| Woodcutter

| Baker

​

///// For each worker type, define here what the worker produces and/or consumes

let workAs = function

| Peasant -> produce 5 Wheat

| Woodcutter -> produce 1 Wood

| Baker -> produce 1 Bread >> consume 1 Wood >> consume 3 Wheat

​

type Worker = {

    Type: WorkerType

    Name: string

    Age: int // years

}

​

let formatWorker worker =

    sprintf "    %A %s (age %d)" worker.Type worker.Name worker.Age

​

let formatWorkers workers =

    workers

    |> Seq.map formatWorker

    |> String.concat "\n"

​

​

let work workers resources =

    workers

    |> Seq.fold (fun res worker -> workAs worker.Type res) resources

​

let eat workers resources =

    resources |> consume (Seq.length workers) Bread

​

let createWorker wtype name age = { Type = wtype; Name = name; Age = age }

​

type Kingdom = {

    Workers: Worker list

    Resources: Resource list

}

​

let formatKingdom kingdom =

    sprintf "Workers:\n%s\nResources:\n%s\n" (formatWorkers kingdom.Workers) (formatResources kingdom.Resources)

​

let endOfTurn kingdom =

    { kingdom with 

        Resources = kingdom.Resources |> work kingdom.Workers |> eat kingdom.Workers }

​

​

​

///// Define your kingdom here. Create any number of Workers and Resources to start with

let myKingdom = {

    Workers = [

        createWorker Peasant "Bob" 32

        createWorker Woodcutter "Heinz" 17

        createWorker Baker "Methusalem" 92

    ]

​

    Resources = [

        createResource Bread 5

    ]

}

​

​

///// Let the game run for a couple turns and then print the state of the kingdom

myKingdom 

|> endOfTurn

|> endOfTurn

|> endOfTurn

|> formatKingdom

|> printf "%s"